PCM: Circle Working Plane Points

[[Mi...]]

To All,

I would like to gain access to a circle feature's working plane point data via PCM. How might I do this? Recall, this is activated clicking the button under "Projection" in a circle feature dialog window.

I would imagine such PCM would use getActual("Feature Name").

Thank you

Mike Roterdam

CircleFeature-WorkingPlane-Points.jpg

[[Mi...]]

Distance D1:  getNominal("-B1-").measElement.projection.measure.distance1

Radius Offset D2:  getNominal("-B1-").measElement.projection.measure.distance2

Distance D3:  getNominal("-B1-").measElement.projection.measure.distance3

Number of Points:  getNominal("-B1-").measElement.projection.measure.numberOfPoints

Start Angle:  getNominal("-B1-").measElement.projection.measure.startAngle

Angle Range:  getNominal("-B1-").measElement.projection.measure.angleSegment.asDEG

[[Mi...]]

Hello Michael,

thank you for the PCM code that gains access to the "Relative Measurement - Three Points" window parameters. I am looking for PCM that gives access to the individual measurement points of the working plane, in my example 3 measurement points. Additionally it would be nice to retrieve the resultant/actual plane data from the N points, if available.

Thank you

Mike Roterdam

[[Mi...]]

Hello!

For Instance you can access the points via

feature="Kreis1"
for i=1 to 3
aa=executeCode("|feat| (((feat:=Zeiss.Calypso.OMInspection active measElements nodeNamed: '"+ feature +"') projection measure generatePoints: feat geometry) at: " + i +") vector")
display(aa)
next i

[[Mi...]]

Wow, deep stuff indeed. I will give it a try. Thank you for your help.

[[Mi...]]

It appears the PCM code provided yields the nominal x, y and z coordinates of the working plane points. I would really like access to each nominal point and nominal vector, along with each actual point and actual vector in such a way to be assigned to the following list of variables:

NomWP1x =
NomWP1y =
NomWP1z =
NomWP1i =
NomWP1j =
NomWP1k =

NomWP2x =
NomWP2y =
NomWP2z =
NomWP2i =
NomWP2j =
NomWP2k =

NomWP3x =
NomWP3y =
NomWP3z =
NomWP3i =
NomWP3j =
NomWP3k =

ActWP1x =
ActWP1y =
ActWP1z =
ActWP1i =
ActWP1j =
ActWP1k =

ActWP2x =
ActWP2y =
ActWP2z =
ActWP2i =
ActWP2j =
ActWP2k =

ActWP3x =
ActWP3y =
ActWP3z =
ActWP3i =
ActWP3j =
ActWP3k =

I appreciate your help

[[Mi...]]

Hello!

feature="Kreis1"
//working plane
workPlane=executeCode("(Zeiss.Calypso.OMInspection active measElements nodeNamed: '"+ feature +"') workingPlaneId")

for i=1 to 5
// norminal point
coord=executeCode("|feat| (((feat:=Zeiss.Calypso.OMInspection active measElements nodeNamed: '"+ feature +"') projection measure generatePoints: feat geometry) at: " + i +") vector")
// norminal vector
normVec=executeCode("|feat| (((feat:=Zeiss.Calypso.OMInspection active measElements nodeNamed: '"+ feature +"') projection measure generatePoints: feat geometry) at: " + i +") normVector negated")

NomWP[i]=point(coord.x, coord.y, coord.z, normVec.x, normVec.y, normVec.z)

// actual point with probe correction
coord=executeCode("|var| var:=((Zeiss.Calypso.OMInspection active actualPart geometry nodeNamed: '"+ workPlane+"')  points at: " + i + ") at: 1. (var vector) + ((var normVector) * (var probeRadius)) ")
// display(round(coord,4))
// actual Vector
normVec=executeCode("|var| var:=((Zeiss.Calypso.OMInspection active actualPart geometry nodeNamed: '"+ workPlane+"')  points at: " + i + ") at: 1. var normVector negated ")
ActWP[i]=point(coord.x, coord.y, coord.z, normVec.x, normVec.y, normVec.z)
next i

The nominal and actual value for the first point in your notation:

NomWP1x =NomWP[1].x
NomWP1y =NomWP[1].y
NomWP1z =NomWP[1].z
NomWP1i =NomWP[1].nx
NomWP1j =NomWP[1].ny
NomWP1k =NomWP[1].nz

ActWP1x =ActWP[1].x
ActWP1y =ActWP[1].y
ActWP1z =ActWP[1].z
ActWP1i =ActWP[1].nx
ActWP1j =ActWP[1].ny
ActWP1k =ActWP[1].nz

Use at your own risk!

[[Mi...]]

I will give it a try. Thanks again for your generous help.

[[Mi...]]

I made some correction.